# Maintainer: krolyxon <me@krolyxon.com>
pkgname=remage-bin
_pkgname=remage
pkgver=0.1.0
pkgrel=1
pkgdesc='Keyboard-centric, GPU-rendered image viewer with vim keys and wallpaper theming'
arch=('x86_64')
url='https://github.com/krolyxon/remage'
license=('AGPL-3.0-only' 'OFL-1.1')
depends=('gcc-libs' 'glibc' 'dav1d' 'libheif' 'libxkbcommon' 'wayland' 'vulkan-icd-loader')
optdepends=(
  'libx11: X11 support'
  'libxcursor: X11 cursors'
  'libxi: X11 input'
  'libxrandr: X11 scaling'
  'mesa: OpenGL fallback'
  'imagemagick: [[decoders]] for PSD, XCF, JP2 and others'
  'wl-clipboard: the example copy command'
  'matugen: wallpaper theming'
  'python-pywal: wallpaper theming'
)
provides=("$_pkgname")
conflicts=("$_pkgname")
options=('!strip' '!debug')
_dir="$_pkgname-v$pkgver-x86_64-linux"
source=("$url/releases/download/v$pkgver/$_dir.tar.gz")
sha256sums=('d9688a8244eacc2aa4daf6b18cea3244fd3aedcf29d142f2efc3c45fa13912dd')

package() {
  cd "$_dir"
  install -Dm755 remage -t "$pkgdir/usr/bin/"
  install -Dm644 remage.1 -t "$pkgdir/usr/share/man/man1/"
  install -Dm644 completions/_remage -t "$pkgdir/usr/share/zsh/site-functions/"
  install -Dm644 completions/remage.bash "$pkgdir/usr/share/bash-completion/completions/remage"
  install -Dm644 completions/remage.fish -t "$pkgdir/usr/share/fish/vendor_completions.d/"
  install -Dm644 contrib/remage.desktop -t "$pkgdir/usr/share/applications/"
  install -Dm644 README.md contrib/config.example.toml -t "$pkgdir/usr/share/doc/$_pkgname/"
  cp -r contrib/matugen contrib/pywal "$pkgdir/usr/share/doc/$_pkgname/"
  install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname/"
  install -Dm644 OFL-fonts.txt -t "$pkgdir/usr/share/licenses/$pkgname/"
}